home *** CD-ROM | disk | FTP | other *** search
/ Scene Storm / Scene Storm - Volume 1.iso / coding / asm / demos / northstardemo / demoreloc.s < prev    next >
Text File  |  1980-01-03  |  27KB  |  1,139 lines
  1. bobs:    equ    34    ;howmany bobs ?
  2.  
  3. ;  All routines made by ATOM of North Star.
  4. ;  The routines have been made to be as simple
  5. ;  and easy to understand as possible, thats
  6. ;  why some of my old(very old) routines
  7. ;  have been used and not the new ones.
  8. ; 
  9. ;  But when you understand the principles
  10. ;  you should have no problems improving
  11. ;  them, and that's the point RIGHT ????
  12. ;
  13. ;  All routines might be used as you want
  14. ;  but the grafix and music is NS property.
  15. ;  
  16. ;  And it would be rather lame-looking if
  17. ;  you used the same font and music.....
  18. ;
  19. ;  Sorry for the late delivery date, but I had to
  20. ;  visit some American software houses for a few
  21. ;  weeks, but better late then never - Right Shredder ?!?
  22.  
  23. ************************************************************
  24. *
  25. *              hardware references
  26. *
  27. ************************************************************
  28.  
  29. custom:     equ        $dff000
  30. bltddat:    equ        $000
  31. dmaconr:    equ        $002
  32. vposr:      equ        $004
  33. vhposr:     equ        $006
  34. dskdatr:    equ        $008
  35. joy0dat:    equ        $00a
  36. joy1dat:    equ        $00c
  37. clxdat:     equ        $00e
  38. adkconr:    equ        $010
  39. pot0dat:    equ        $012
  40. pot1dat:    equ        $014
  41. potgor:     equ        $016
  42. serdatr:    equ        $018
  43. dskbytr:    equ        $01a
  44. intenar:    equ        $01c
  45. intreqr:    equ        $01e
  46. dskpth:     equ        $020
  47. dskptl:     equ        $022
  48. dsklen:     equ        $024
  49. dskdat:     equ        $026
  50. refptr:     equ        $028
  51. vposw:      equ        $02a
  52. vhposw:     equ        $02c
  53. copcon:     equ        $02e
  54. serdat:     equ        $030
  55. serper:     equ        $032
  56. potgo:      equ        $034
  57. joytest:    equ        $036
  58. strequ:     equ        $038
  59. strvbl:     equ        $03a
  60. strhor:     equ        $03c
  61. strlong:    equ        $03e
  62. bltcon0:    equ        $040
  63. bltcon1:    equ        $042
  64. bltafwm:    equ        $044
  65. bltalwm:    equ        $046
  66. bltcpth:    equ        $048
  67. bltcptl:    equ        $04a
  68. bltbpth:    equ        $04c
  69. bltbptl:    equ        $04e
  70. bltapth:    equ        $050
  71. bltaptl:    equ        $052
  72. bltdpth:    equ        $054
  73. bltdptl:    equ        $056
  74. bltsize:    equ        $058
  75. bltcmod:    equ        $060
  76. bltbmod:    equ        $062
  77. bltamod:    equ        $064
  78. bltdmod:    equ        $066
  79. bltcdat:    equ        $070
  80. bltbdat:    equ        $072
  81. bltadat:    equ        $074
  82. dsksync:    equ        $07e
  83. cop1lch:    equ        $080
  84. cop1lcl:    equ        $082
  85. cop2lch:    equ        $084
  86. cop2lcl:    equ        $086
  87. copjmp1:    equ        $088
  88. copjmp2:    equ        $08a
  89. copins:     equ        $08c
  90. diwstrt:    equ        $08e
  91. diwstop:    equ        $090
  92. ddfstrt:    equ        $092
  93. ddfstop:    equ        $094
  94. dmacon:     equ        $096
  95. clxcon:     equ        $098
  96. intena:     equ        $09a
  97. intreq:     equ        $09c
  98. adkcon:     equ        $09e
  99. aud0lch:    equ        $0a0
  100. aud0lcl:    equ        $0a2
  101. aud0len:    equ        $0a4
  102. aud0per:    equ        $0a6
  103. aud0vol:    equ        $0a8
  104. aud0dat:    equ        $0aa
  105. aud1lch:    equ        $0b0
  106. aud1lcl:    equ        $0b2
  107. aud1len:    equ        $0b4
  108. aud1per:    equ        $0b6
  109. aud1vol:    equ        $0b8
  110. aud1dat:    equ        $0ba
  111. aud2lch:    equ        $0c0
  112. aud2lcl:    equ        $0c2
  113. aud2len:    equ        $0c4
  114. aud2per:    equ        $0c6
  115. aud2vol:    equ        $0c8
  116. aud2dat:    equ        $0ca
  117. aud3lch:    equ        $0d0
  118. aud3lcl:    equ        $0d2
  119. aud3len:    equ        $0d4
  120. aud3per:    equ        $0d6
  121. aud3vol:    equ        $0d8
  122. aud3dat:    equ        $0da
  123. bpl1pth:    equ        $0e0
  124. bpl1ptl:    equ        $0e2
  125. bpl2pth:    equ        $0e4
  126. bpl2ptl:    equ        $0e6
  127. bpl3pth:    equ        $0e8
  128. bpl3ptl:    equ        $0ea
  129. bpl4pth:    equ        $0ec
  130. bpl4ptl:    equ        $0ee
  131. bpl5pth:    equ        $0f0
  132. bpl5ptl:    equ        $0f2
  133. bpl6pth:    equ        $0f4
  134. bpl6ptl:    equ        $0f6
  135. bplcon0:    equ        $100
  136. bplcon1:    equ        $102
  137. bplcon2:    equ        $104
  138. bpl1mod:    equ        $108
  139. bpl2mod:    equ        $10a
  140. bpl1dat:    equ        $110
  141. bpl2dat:    equ        $112
  142. bpl3dat:    equ        $114
  143. bpl4dat:    equ        $116
  144. bpl5dat:    equ        $118
  145. bpl6dat:    equ        $11a
  146. spr0pth:    equ        $120
  147. spr0ptl:    equ        $122
  148. spr1pth:    equ        $124
  149. spr1ptl:    equ        $126
  150. spr2pth:    equ        $128
  151. spr2ptl:    equ        $12a
  152. spr3pth:    equ        $12c
  153. spr3ptl:    equ        $12e
  154. spr4pth:    equ        $130
  155. spr4ptl:    equ        $132
  156. spr5pth:    equ        $134
  157. spr5ptl:    equ        $136
  158. spr6pth:    equ        $138
  159. spr6ptl:    equ        $13a
  160. spr7pth:    equ        $13c
  161. spr7ptl:    equ        $13e
  162. spr0pos:    equ        $140
  163. spr0ctl:    equ        $142
  164. spr0data:   equ        $144
  165. spr0datb:   equ        $146
  166. spr1pos:    equ        $148
  167. spr1ctl:    equ        $14a
  168. spr1data:   equ        $14c
  169. spr1datb:   equ        $14e
  170. spr2pos:    equ        $150
  171. spr2ctl:    equ        $152
  172. spr2data:   equ        $154
  173. spr2datb:   equ        $156
  174. spr3pos:    equ        $158
  175. spr3ctl:    equ        $15a
  176. spr3data:   equ        $15c
  177. spr3datb:   equ        $15e
  178. spr4pos:    equ        $160
  179. spr4ctl:    equ        $162
  180. spr4data:   equ        $164
  181. spr4datb:   equ        $166
  182. spr5pos:    equ        $168
  183. spr5ctl:    equ        $16a
  184. spr5data:   equ        $16c
  185. spr5datb:   equ        $16e
  186. spr6pos:    equ        $170
  187. spr6ctl:    equ        $172
  188. spr6data:   equ        $174
  189. spr6datb:   equ        $176
  190. spr7pos:    equ        $178
  191. spr7ctl:    equ        $17a
  192. spr7data:   equ        $17c
  193. spr7datb:   equ        $17e
  194. color00:    equ        $180
  195. color01:    equ        $182
  196. color02:    equ        $184
  197. color03:    equ        $186
  198. color04:    equ        $188
  199. color05:    equ        $18a
  200. color06:    equ        $18c
  201. color07:    equ        $18e
  202. color08:    equ        $190
  203. color09:    equ        $192
  204. color10:    equ        $194
  205. color11:    equ        $196
  206. color12:    equ        $198
  207. color13:    equ        $19a
  208. color14:    equ        $19c
  209. color15:    equ        $19e
  210. color16:    equ        $1a0
  211. color17:    equ        $1a2
  212. color18:    equ        $1a4
  213. color19:    equ        $1a6
  214. color20:    equ        $1a8
  215. color21:    equ        $1aa
  216. color22:    equ        $1ac
  217. color23:    equ        $1ae
  218. color24:    equ        $1b0
  219. color25:    equ        $1b2
  220. color26:    equ        $1b4
  221. color27:    equ        $1b6
  222. color28:    equ        $1b8
  223. color29:    equ        $1ba
  224. color30:    equ        $1bc
  225. color31:    equ        $1be
  226.  
  227.  
  228. ************************************************************
  229. *
  230. *              clist.lib.offsets
  231. *
  232. ************************************************************
  233.  
  234.  
  235. initclpool:     equ            -30
  236. allocclist:     equ            -36
  237. freeclist:      equ            -42
  238. flushclist:     equ            -48
  239. sizeclist:      equ            -54
  240. putclchar:      equ            -60
  241. getclchar:      equ            -66
  242. ungetclchar:    equ            -72
  243. unputlcchar:    equ            -78
  244. putclword:      equ            -84
  245. getclword:      equ            -90
  246. ungetclword:    equ            -96
  247. unputclword:    equ            -102
  248. putclbuf:       equ            -108
  249. getclbuf:       equ            -114
  250. markclist:      equ            -120
  251. incrclmark:     equ            -126
  252. peekclmark:     equ            -132
  253. splitclist:     equ            -138
  254. copyclist:      equ            -144
  255. subclist:       equ            -150
  256. concatclist:    equ            -156
  257.  
  258.  
  259. ************************************************************
  260. *
  261. *              console.lib.offsets
  262. *
  263. ************************************************************
  264.  
  265.  
  266. cdinputhandler: equ            -42
  267. rawkeyconvert:  equ            -48
  268.  
  269.  
  270. ************************************************************
  271. *
  272. *              diskfont.lib.offsets
  273. *
  274. ************************************************************
  275.  
  276.  
  277. opendiskfont:   equ            -30
  278. availfonts:     equ            -36
  279.  
  280.  
  281. ************************************************************
  282. *
  283. *              dos.lib/offsets
  284. *
  285. ***********************************************************
  286.  
  287.  
  288. open:           equ            -30
  289. close:          equ            -36
  290. read:           equ            -42
  291. write:          equ            -48
  292. input:          equ            -54
  293. output:         equ            -60
  294.  
  295.  
  296. ************************************************************
  297. *
  298. *              exec.lib.offsets
  299. *
  300. ************************************************************
  301.  
  302.  
  303. absexecbase:    equ            4
  304. allocmem:       equ            -198
  305. freemem:        equ            -210
  306. getmsg:         equ            -372
  307. replymsg:       equ            -378
  308. waitport:       equ            -384
  309. closelibrary:   equ            -414
  310. opendevice:     equ            -444
  311. closedevice:    equ            -450
  312. doio:           equ            -456
  313. openlibrary:    equ            -552
  314.  
  315.  
  316. ************************************************************
  317. *
  318. *              intuition.lib.offsets
  319. *
  320. ************************************************************
  321.  
  322.  
  323. clearmenustrip: equ            -54
  324. closescreen:    equ            -66
  325. closewindow:    equ            -72
  326. openscreen:     equ            -198
  327. openwindow:     equ            -204
  328. printitext:     equ            -216
  329. setmenustrip:   equ            -264
  330. showtitle:      equ            -282
  331. viewportaddress: equ           -300
  332. windowtoback:   equ            -306
  333. windowtofront:  equ            -312
  334.  
  335.  
  336. ************************************************************
  337. *
  338. *              graphics.lib.offsets
  339. *
  340. ************************************************************
  341.  
  342.  
  343. loadrgb4:       equ            -192
  344. setrgb4:        equ            -288
  345. aa    bsr    go
  346. bb    rts
  347.     
  348. go:    move.l    4.w,a6
  349.     jsr    -132(a6)
  350.  
  351.     move.l    #frimem,d0
  352.     move.l    d0,bobmem1
  353.     add.l    #16000,d0
  354.     move.l    d0,bobmem2    ;bob bpl mem
  355.     add.l    #16000,d0
  356.     move.l    d0,megaspr    ;memory for sprite data
  357.     add.l    #2000,d0    
  358.     move.l    d0,scrmem1
  359.     add.l    #4224,d0
  360.     move.l    d0,scrmem2
  361.     add.l    #4224,d0
  362.     move.l    d0,scrmem3
  363.     add.l    #4224+8000,d0
  364.     move.l    d0,copmem
  365.  
  366.     bsr    flipp
  367.  
  368.     lea    $dff000,a0
  369.     move.w    #$4000,intena(a0)
  370.     move.w    dmaconr(a0),d0
  371.     or.w    #$8000,d0
  372.     move.w    d0,dmasaf
  373.  
  374.     move.w    #$7fff,dmacon(a0)
  375.     move.w    #%1000011111101111,dmacon(a0)
  376.  
  377.     bsr    makecop
  378.  
  379.     move.l    copmem,a1
  380.     move.l    a1,cop1lch(a0)
  381.     clr.w    copjmp1(a0)
  382.  
  383.     bsr    makespr
  384.  
  385.     move.l    #scrtext,scrpoint
  386.     bsr    fixbobsin
  387.  
  388.     bsr    calcbob
  389.  
  390.  
  391. ********* Main Program **********
  392.  
  393. main:    lea    $dff000,a0
  394.     and.w    #$20,intreqr(a0)
  395.     beq.s    main
  396.     move.w    #$20,intreq(a0)    
  397.  
  398.     bsr    stars
  399.  
  400.     bsr    calclogo
  401.  
  402.     bsr    clrbobs            ;clear bobs
  403.     bsr    putbobs            ;blit bobs
  404.     bsr    flipp            ;change bob pictures
  405.  
  406. crick:    cmp.b    #180,$dff000+vhposr    ;timing
  407.     blt.s    crick
  408.  
  409.     bsr    scroll        ;move scroll and put new chr
  410.     bsr    setlogo        ;and scroll copper pointers
  411.     bsr    calcbob        ;calc new bob pos
  412.  
  413.     btst    #6,$bfe001
  414.     bne.s    main
  415.  
  416. *********** Exit *************
  417.  
  418.     move.w    #$7fff,dmacon+$dff000
  419.     move.l    4.w,a6
  420.     jsr    -138(a6)
  421.     lea    grlib(pc),a1
  422.     jsr    -408(a6)
  423.     move.l    d0,a0
  424.     move.l    38(a0),$dff080
  425.     move.w    #0,copjmp1+$dff000
  426.     move.w    dmasaf,d0
  427.     move.w    d0,dmacon+$dff000
  428.  
  429.  
  430.     move.w    #$c000,$df000+intena
  431.     moveq    #0,d0
  432. error:    rts
  433.  
  434. ********** Sub Routines ************
  435. ;  This routine sets the grade value for the bobs
  436. ;
  437. fixbobsin:
  438.     move.w    #bobs,d0
  439.     lea    bobsin,a1
  440.     lea    bobcos,a2
  441.     clr.w    d1
  442.     clr.w    d2
  443. bobsin1:move.w    d1,(a1)+
  444.     move.w    d2,(a2)+
  445.     add.w    #8,d1        ;add value to next grade (try to chg)
  446.     add.w    #12,d2
  447.     dbf    d0,bobsin1
  448.     rts
  449.  
  450. ***********************************
  451. ;  This routine calls the sine and cosine routines
  452. ;  to calculate new positions for the bobs, normally
  453. ;  when you run the same track again and again you
  454. ;  make the sin/cos calcs before and puts them in
  455. ;  memory so you just have to fetch them.
  456.  
  457. calcbob:move.w    #bobs,d7
  458.     lea    bobsin,a1    ;pointers to grade
  459.     lea    bobcos,a2
  460.     lea    boby,a3        ;pointers to positions
  461.     lea    bobx,a4
  462.     clr.l    d0
  463. cbob1:    move.w    (a1),d0        ;get y grade
  464.     addq.w    #4,d0        ;add a value (try to change it!)
  465.     cmp.w    #360,d0        ;check not exciding 360
  466.     blt.s    cbob2
  467.     sub.w    #360,d0
  468. cbob2:    move.w    d0,(a1)+    ;grade y
  469.     move.l    #100,d2        ;origo y
  470.     move.w    #80,d1        ;radius y
  471.     bsr    getsin
  472.     move.w    d3,(a3)+    ;set y pos
  473.     
  474.     move.w    (a2),d0        ;this is the same as the sin
  475.     addq.w    #2,d0        ;just handling cos instead.
  476.     cmp.w    #360,d0
  477.     blt.s    cbob3
  478.     sub.w    #360,d0
  479. cbob3:    move.w    d0,(a2)+    ;grade x
  480.     move.w    #160-8,d2    ;origo x
  481.     move.w    #120,d1        ;radius x
  482.     bsr    getcos
  483.     move.w    d3,(a4)+    ;set x pos
  484.     dbf    d7,cbob1
  485.     rts
  486.  
  487. ************************************
  488. ;This flipps the screen so the pict just finished is
  489. ;shown and the other one will be worked with.
  490.  
  491. ;
  492. flipp:    move.l    bobmem1,d0
  493.     cmp.l    bobshow,d0
  494.     beq.s    flipp2
  495.     move.l    bobmem1,bobshow
  496.     move.l    bobmem2,bobwork
  497.     move.l    #clear2,clearp
  498.     rts
  499.  
  500. flipp2:    move.l    bobmem2,bobshow
  501.     move.l    bobmem1,bobwork
  502.     move.l    #clear1,clearp
  503.     rts
  504.  
  505.  
  506.  
  507. ************************************
  508. ; This is the bob routine, with buffering,
  509. ; that is that every frame you work with
  510. ; the bobsmem not shown and you show the other
  511.  
  512. ; Buffering is used so that you can blit the bobs
  513. ; during the whole frame without flickering. 
  514.  
  515. ; This is used in every serious game. But it takes
  516. ; the double amount of memory....
  517.  
  518. ; The new way to blit multiple bitplanes is NOT
  519. ; used, that might would have been too hard to
  520. ; understand....
  521.  
  522. clrbobs:move.l    clearp,a4
  523.     move.l    bobwork,d1
  524.     lea    $dff000,a0
  525.     move.w    #36,bltdmod(a0)
  526.     move.w    #$100,bltcon0(a0); use only destination
  527. clr1:    move.l    (a4)+,d0    ;fetch clr add
  528.     tst.l    d0
  529.     beq    error
  530.     add.l    d1,d0
  531. clr2:    btst    #6,dmaconr(a0)    ;blt nasty doesn't work with only
  532.     bne.s    clr2        ;destination.....
  533.     move.l    d0,bltdpth(a0)
  534.     move.w    #$3c2,bltsize(a0)
  535.     add.l    #8000,d0    ;clear next bitpl
  536. clr3:    btst    #6,dmaconr(a0)
  537.     bne.s    clr3
  538.     move.l    d0,bltdpth(a0)
  539.     move.w    #$3c2,bltsize(a0)
  540. clr4:    btst    #6,dmaconr(a0)
  541.     bne.s    clr4
  542.     bra.s    clr1
  543.  
  544.  
  545. putbobs:
  546.     move.w    #bobs,d0
  547.     lea    boby,a1        ;ypos in a1
  548.     lea    bobx,a2        ;xpos in a2
  549.     lea    $dff000,a0
  550.     move.l    #$ffff0000,bltafwm(a0)    ;mask off the 16 last bits
  551.     move.w    #36,bltdmod(a0)        ;40-4=36
  552.     move.w    #-2,bltamod(a0)        ;This is done becourse you have to
  553.     move.w    #-2,bltbmod(a0)        ;blit one word more to rotate bob.
  554.     move.w    #36,bltcmod(a0)
  555.  
  556. ;A is mask
  557. ;B is gfx data
  558. ;C is screen
  559. ;D is screen
  560.  
  561. putbob1:
  562.     move.l    bobwork,a3    ;destination in a3
  563.     move.w    (a1)+,d1    ;ypos in d1
  564.     move.w    (a2)+,d2    ;xpos in d2
  565.     mulu    #40,d1        ;mulu with screen width
  566.     move.w    d2,d3
  567.     and.w    #15,d3        ;get scroll value in d3
  568.     lsr.w    #3,d2        ;divide with 8 to get byte
  569.     add.w    d2,d1
  570.     move.l    clearp,a4    ;save the addr for clearing of bob
  571.     move.l    d1,(a4)+
  572.     move.l    a4,clearp
  573.     add.l    d1,a3        ;a3 now points to right dest.
  574.     ror.w    #4,d3        ;get scr val in high bits
  575.     move.w    d3,bltcon1(a0)    ;scr value for grfx
  576.     or.w    #$fca,d3    ;use ABCD
  577.  
  578. ; C and A, C or B -> D
  579. ;
  580. ;
  581.     move.w    d3,bltcon0(a0)    ;scr value for mask
  582.  
  583.     move.l    #bobraw,bltbpth(a0)
  584.     move.l    #bobmaskraw,bltapth(a0)
  585.     move.l    a3,bltdpth(a0)
  586.     move.l    a3,bltcpth(a0)
  587.  
  588.     move.w    #$3c2,bltsize(a0)
  589. waitb1:    btst    #6,dmaconr(a0)
  590.     bne.s    waitb1
  591.  
  592.     add.l    #8000,a3    ;next bpl
  593.     move.l    #bobraw+30,bltbpth(a0)
  594.     move.l    #bobmaskraw,bltapth(a0)
  595.     move.l    a3,bltdpth(a0)
  596.     move.l    a3,bltcpth(a0)
  597.     move.w    #$3c2,bltsize(a0)
  598.  
  599. waitb2:    btst    #6,dmaconr(a0)
  600.     bne.s    waitb2
  601.  
  602.     dbf    d0,putbob1
  603.     move.l    clearp,a4    ;make a zero last in the list
  604.     clr.l    (a4)
  605.     rts
  606.  
  607. ************************************
  608. ;This calcs the bumping logo
  609. ;
  610. ;
  611. ;
  612.  
  613. calclogo:
  614.     tst.w    wait1    ;check if wait
  615.     beq.s    ok1
  616.     subq.w    #1,wait1
  617.     rts
  618. ok1:    addq.w    #2,logograd
  619.     cmp.w    #180,logograd
  620.     blt.s    slipp1
  621.     clr.w    logograd
  622. slipp1:    cmp.w    #90,logograd    ;make a pause when 90 reached
  623.     bne.s    ok2
  624.     move.w    #200,wait1    ;wait 200 frames
  625. ok2:    clr.l    d0
  626.     move.w    logograd,d0    ;grade
  627.     add.w    #180,d0
  628.     move.l    #100,d1        ;radius
  629.     move.l    #104,d2        ;origo
  630.     bsr    getsin
  631.     move.w    d3,logoy    ;put new y pos
  632.     rts    
  633.  
  634. ************************************
  635. ;The actual scroll routine
  636. ;
  637. ;
  638. scroll:    tst.w    pause        ;pause ?
  639.     beq    scroll99
  640.     subq.w    #1,pause
  641.     rts
  642. scroll99:move.w    speed,d0
  643.     add.w    d0,scrcount    ;add speed (pixels)
  644.     move.w    scrcount,d0
  645.     lsr.w    #3,d0        ;pix/8
  646.     move.w    d0,scradd
  647.     move.w    scrcount,d0
  648.     and.w    #31,d0
  649.     bne    error        ;new char to put out ?
  650. scroll1:move.l    scrpoint,a1    ;Yep !
  651.     clr.l    d0
  652. scroll6:move.b    (a1)+,d0    ;get ascII in d0
  653.     cmp.w    #'^',d0        ;end of scroll ?
  654.     bne.s    scroll2
  655.     move.l    #scrtext,scrpoint
  656.     bra.s    scroll1
  657. scroll2:cmp.w    #31,d0
  658.     bgt.s    scroll5
  659.     move.w    d0,speed
  660.     bra.s    scroll6
  661. scroll5:cmp.w    #'#',d0        ;check if pause
  662.     bne.s    scroll7
  663.     move.w    #50,pause
  664.     bra.s    scroll6
  665. scroll7:move.l    a1,scrpoint
  666.     lea    fontraw,a5    ;Some math to calc char pos in bitmap
  667.     sub.w    #32,d0        ;space=0
  668.     move.w    d0,d1
  669.     divu    #10,d0        ;divide by number of chars per row
  670.     move.w    d0,d2
  671.     mulu    #1280,d0    ;multiply with one row 32*40=1280
  672.     add.l    d0,a5        ;now we point to the right row
  673.     mulu    #10,d2
  674.     sub.w    d2,d1
  675.     lsl.w    #2,d1        ;multiply with one char width 4bytes
  676.     add.w    d1,a5        ;a5 points to char in bitmap. GREAT !!
  677.  
  678.     move.l    scrmem1,a4    ;pointer to start of screen
  679.     add.l    #40,a4        ;put char on right side of screen
  680.     clr.l    d7
  681.     move.w    scradd,d7
  682.     add.l    d7,a4        ;add the scradd.
  683.  
  684.     lea    $dff000,a0    ;lets BLITT !!
  685.     move.l    #$ffffffff,bltafwm(a0)    ;no mask
  686.     move.w    #40,bltdmod(a0)    ;44-4=40
  687.     move.w    #36,bltamod(a0)    ;40-4=36
  688.     move.w    #$9f0,bltcon0(a0); D=A minterm
  689.     clr.w    bltcon1(a0)
  690.  
  691.     move.l    a4,bltdpth(a0)
  692.     move.l    a5,bltapth(a0)    ;bpl 1
  693.     move.w    #$802,bltsize(a0)
  694. waitb4:    btst    #6,dmaconr(a0)
  695.     bne.s    waitb4
  696.  
  697.     add.l    #4224,a4
  698.     add.l    #7680,a5    ;bpl 2
  699.     move.l    a4,bltdpth(a0)
  700.     move.l    a5,bltapth(a0)
  701.     move.w    #$802,bltsize(a0)
  702. waitb5:    btst    #6,dmaconr(a0)
  703.     bne.s    waitb5
  704.  
  705.     add.l    #4224,a4
  706.     add.l    #7680,a5    ;bpl 3
  707.     move.l    a4,bltdpth(a0)
  708.     move.l    a5,bltapth(a0)
  709.     move.w    #$802,bltsize(a0)
  710. waitb6:    btst    #6,dmaconr(a0)
  711.     bne.s    waitb6
  712.     rts
  713.     
  714.     
  715.  
  716. ***********************************
  717.  
  718.  
  719. ** this moves the stars to the right **
  720. ; you can speed this routine up to half
  721. ; the raster time if you change the cmp.l 
  722. ; to cmp.w , but then you have to change
  723. ; data struct in makespr aswell.
  724. ; (You have to do something yourself!!)
  725. stars:    move.l    megaspr,a1    
  726.     bsr    plupp
  727.     move.l    megaspr,a1
  728.     add.l    #1000,a1    
  729. plupp:    cmp.w    #0,(a1)
  730.     beq    error
  731.     move.w    (a1),d0
  732.     cmp.l    #$00010001,4(a1)    ;dark color ? ($555)
  733.     beq.s    slow
  734.     cmp.l    #$00000001,4(a1)    ;normal grey ?($aaa)
  735.     beq.s    medel
  736.     addi.b    #1,d0            ;bright stars ? move 3 steps
  737. medel:    addi.b    #1,d0    ;change these to sub to move left.
  738. slow:    addi.b    #1,d0
  739.     move.b    d0,1(a1)
  740.     add.l    #8,a1
  741.     bra    plupp
  742. blill:    clr.w    (a2)+
  743.     rts
  744.  
  745. ;This routine doesn't work on sprites below 255.
  746. ;But it's not hard to change it or re-write it 
  747. ;these stars routines was written a year ago....
  748.  
  749. makespr:lea    $fc0000,a3    ;creates a long random x sprite
  750.     move.l    megaspr,a2    ;at address a2
  751.     bsr    espr        ;starty in d5
  752.     move.l    megaspr,a2
  753.     add.l    #1000,a2
  754. espr:    move.l    #44,d5
  755.     move.w    #1,d4
  756. klick:    move.w    d5,d1
  757.     add.w    #2,d5
  758.     rol.w    #8,d1
  759.     move.w    d1,d3
  760.     move.w    (a3)+,d2
  761.     move.w    50(a3),d4
  762.     eor.w    d4,d2
  763.     and.l    #$ff,d2
  764.     or.w    d2,d1
  765.     move.w    d1,(a2)+
  766.     and.l    #$ff00,d3
  767.     add.w    #$100,d3
  768.     move.w    d3,(a2)+
  769.     move.w    (a3)+,d1
  770.     eor.w    d4,d1
  771.     and.w    #3,d1
  772.     cmp.w    #1,d1
  773.     bne.s    bop1
  774.     move.w    #1,d6
  775.     move.w    #0,d7
  776. bop1:    cmp.w    #2,d1
  777.     bne.s    bop2
  778.     move.w    #0,d6
  779.     move.w    #1,d7
  780. bop2:    cmp.w    #3,d1
  781.     bne.s    bop3
  782.     move.w    #1,d6
  783.     move.w    #1,d7
  784. bop3:    move.w    d6,(a2)+
  785.     move.w    d7,(a2)+
  786.     cmp.w    #244,d5        ;200 lines done ?
  787.     beq    blill        ;exit ?
  788.     bra    klick
  789.  
  790.  
  791.  
  792.  
  793. ***********************************
  794. ;This is the routine wich creates the whole
  795. ;copper list, most programmes write there copper list
  796. ;in a table.. But I find this way easier when you create
  797. ;complex copper lists with lot of colors and changeses.
  798. ;
  799.  
  800. makecop:move.l    copmem,a2        ;get copper addr in a2
  801.     move.w    #bpl2mod,(a2)+
  802.     clr.w    (a2)+
  803.     move.w    #bplcon0,(a2)+
  804.     move.w    #$5400,(a2)+        ;3 bitpl logo & 2 bitpl bobs
  805.     move.w    #color00,(a2)+
  806.     clr.w    (a2)+
  807.  
  808.     move.w    #$106,(a2)+        ;bplcon4
  809.     move.w    #0,(a2)+        ;clear it
  810.  
  811.     move.w    #$1fc,(a2)+        ;fetch mode
  812.     move.w    #0,(a2)+        ;clear it
  813.  
  814.     move.w    #bplcon2,(a2)+        ;plf 1 first, plf 2 after
  815.     move.w    #0,(a2)+        ;spr last
  816.     move.w    #bplcon1,(a2)+        ;correct scr value
  817.     move.w    #0,(a2)+
  818.     move.w    #ddfstrt,(a2)+        ;setup screen
  819.     move.w    #$0038,(a2)+        ;200*40
  820.     move.w    #ddfstop,(a2)+
  821.     move.w    #$00d0,(a2)+
  822.     move.w    #diwstrt,(a2)+
  823.     move.w    #$2c81,(a2)+
  824.     move.w    #diwstop,(a2)+
  825.     move.w    #$f4c1,(a2)+
  826.     move.l    #nslogoraw,d1        ;set bitplane pointers
  827.     move.w    #bpl1pth,d0
  828.     bsr    setbpl
  829.     add.l    #2480,d1    ;logo y*40
  830.     move.w    #bpl3pth,d0
  831.     bsr    setbpl
  832.     add.l    #2480,d1    ;logo y*40
  833.     move.w    #bpl5pth,d0
  834.     bsr    setbpl
  835.     move.w    #spr0pth,d0        ;set sprite pointers
  836.     move.l    megaspr,d1
  837.     bsr    setbpl
  838.     move.w    #spr1pth,d0
  839.     add.l    #1000,d1
  840.     bsr    setbpl
  841.     move.w    #spr2pth,d0        ;rest of the spr to dummy
  842.     move.l    #tom,d1            ;address.
  843.     bsr    setbpl
  844.     move.w    #spr3pth,d0
  845.     move.l    #tom,d1
  846.     bsr    setbpl
  847.     move.w    #spr4pth,d0
  848.     move.l    #tom,d1
  849.     bsr    setbpl
  850.     move.w    #spr5pth,d0
  851.     move.l    #tom,d1
  852.     bsr    setbpl
  853.     move.w    #spr6pth,d0
  854.     move.l    #tom,d1
  855.     bsr    setbpl
  856.     move.w    #spr7pth,d0
  857.     move.l    #tom,d1
  858.     bsr    setbpl
  859.                     ;Set colors
  860.     lea    nslogoraw+7440,a1    ;point to colors
  861.     move.w    #7,d1            ;set 8 colors
  862.     move.w    #color00,d0
  863.     bsr    setcol
  864.     lea    sprcol,a1
  865.     move.w    #3,d1
  866.     move.w    #color16,d0
  867.     bsr    setcol
  868.  
  869.     lea    bobraw+60,a1
  870.     move.w    #3,d1
  871.     move.w    #color08,d0
  872.     bsr    setcol
  873.  
  874.     move.w    #bpl1mod,(a2)+    ;logo off
  875.     move.w    #-40,(a2)+
  876.     pea    next1
  877.     move.l    a2,agg1
  878.  
  879. ** jump to this every vb to move logo to logoy **
  880. ;  Make sure that the logo doesn't reach the scroll !!!
  881. ;  This also shifts the bob screens
  882.  
  883. setlogo:move.l    agg1,a2
  884.     move.l    bobshow,d1    ;show picture not working with
  885.     move.w    #bpl2pth,d0
  886.     bsr    setbpl
  887.     add.l    #8000,d1
  888.     move.w    #bpl4pth,d0
  889.     bsr    setbpl
  890.  
  891.     move.w    logoy,d0
  892.     add.w    #44,d0        ;add vb length
  893.     lsl.w    #8,d0        ;ypos in highbyte
  894.     or.w    #1,d0        ;set bit 0
  895.     move.w    d0,(a2)+    ;wait logoy
  896.     move.w    #$ff00,(a2)+
  897.     move.w    #bpl1mod,(a2)+
  898.     clr.w    (a2)+        ;clr bplmod1, show logo
  899.  
  900.     move.w    d0,d2        ;set the colbar in the logo
  901.     move.w    logoby,d1    ;at poss logoby
  902.     lsl.w    #8,d1
  903.     add.w    d1,d2
  904.     lea    colbar3,a1
  905.     move.w    #31,d3
  906. intact:    move.w    d2,(a2)+
  907.     move.w    #$ff00,(a2)+
  908.     move.w    #color07,(a2)+
  909.     move.w    (a1)+,(a2)+
  910.     add.w    #$0100,d2
  911.     dbf    d3,intact
  912.  
  913.  
  914.     add.w    #$3d00,d0    ;show 61 lines of logo
  915.     move.w    d0,(a2)+    ;wait untill last line
  916.     move.w    #$ff00,(a2)+
  917.     move.w    #bpl1mod,(a2)+
  918.     move.w    #-40,(a2)+    ;turn logo off again.
  919.     move.w    #bpl1pth,d0
  920.     move.l    #tom,d1
  921.     bsr    setbpl    
  922.     move.w    #bpl3pth,d0
  923.     move.l    #tom,d1
  924.     bsr    setbpl    
  925.     move.w    #bpl5pth,d0
  926.     move.l    #tom,d1
  927.     bsr    setbpl    
  928.  
  929.     lea    fontraw+23040,a1    ;set scroll color
  930.     move.w    #color00,d0
  931.     move.w    #7,d1
  932.     bsr    setcol
  933.  
  934. ** this will set the bplpth's and bplcon1 for the scroll **
  935.  
  936.     move.w    #$d401,(a2)+    ;put scr at line 212
  937.     move.w    #$ff00,(a2)+
  938.     move.w    #ddfstrt,(a2)+    ;new screen width 42
  939.     move.w    #$0032,(a2)+
  940.     move.w    #bpl2mod,(a2)+    ;correct for plf 2
  941.     move.w    #-2,(a2)+
  942.     move.w    #bpl1mod,(a2)+
  943.     move.w    #2,(a2)+    ;module 2, sceen 44 bytes
  944.     move.w    scrcount,d0
  945.     and.w    #15,d0
  946.     not.w    d0
  947.     move.w    #bplcon1,(a2)+    ;plf 2=$f
  948.     move.w    d0,(a2)+
  949.     clr.l    d7
  950.     move.w    scrcount,d7
  951.     lsr.w    #3,d7
  952.     move.w    #bpl1pth,d0
  953.     move.l    scrmem1,d1
  954.     add.l    d7,d1
  955.     bsr    setbpl
  956.     move.w    #bpl3pth,d0
  957.     move.l    scrmem2,d1
  958.     add.l    d7,d1
  959.     bsr    setbpl
  960.     move.w    #bpl5pth,d0
  961.     move.l    scrmem3,d1
  962.     add.l    d7,d1
  963.     bsr    setbpl
  964.     rts
  965.  
  966. next1:    move.w    #$d40b,d0    ;legendary Ns Red Bars (C) NS
  967.     move.w    #31,d1
  968.     lea    colbar1,a1
  969. next2:    move.w    d0,(a2)+
  970.     move.w    #$fffe,(a2)+
  971.     add.w    #$0100,d0
  972.     move.w    #color00,(a2)+
  973.     move.w    (a1)+,(a2)+
  974.     lea    colbar2,a3    ;Lets make some horizontal bars !!
  975.     move.w    #42,d2
  976. next3:    move.w    #color01,(a2)+
  977.     move.w    (a3)+,(a2)+
  978.     dbf    d2,next3
  979.  
  980.     dbf    d1,next2
  981.  
  982. leave:    move.l    #$fffffffe,(a2)    ;end of copper list !!!!
  983.     rts
  984.  
  985. *** color poiner in a1..coloraddr in d0..howmany in d1
  986.  
  987. setcol:    move.w    d0,(a2)+
  988.     move.w    (a1)+,(a2)+
  989.     addq.w    #2,d0
  990.     dbf    d1,setcol
  991.     rts
  992.  
  993. *** mem in d1....bpl in d0****
  994.  
  995. setbpl:    move.w    d0,(a2)+
  996.     swap    d1
  997.     move.w    d1,(a2)+
  998.     swap    d1
  999.     addq.w    #2,d0
  1000.     move.w    d0,(a2)+
  1001.     move.w    d1,(a2)+
  1002.     rts
  1003.  
  1004. *****************************************
  1005. ;
  1006. ;    d0-grad    d1-rad   d2-origo
  1007. ;=>    d3-pos
  1008.  
  1009. getsin:    cmp.w    #360,d0        ;test if spinn.
  1010.     ble.s    getsin2
  1011.     sub.w    #360,d0
  1012.     bra.s    getsin
  1013. getsin2:lea    sine,a0
  1014.     lsl.w    #1,d0
  1015.     move.w    (a0,d0),d3
  1016.     muls    d1,d3
  1017.     lsr.l    #7,d3
  1018.     add.l    d2,d3
  1019.     and.l    #$fff,d3
  1020.     rts
  1021.  
  1022. getcos:    cmp.w    #360,d0        ;test if spinn.
  1023.     ble.s    getcos2
  1024.     sub.w    #360,d0
  1025.     bra.s    getcos
  1026. getcos2:lea    sine+180,a0
  1027.     lsl.w    #1,d0
  1028.     move.w    (a0,d0),d3
  1029.     muls    d1,d3
  1030.     lsr.l    #7,d3
  1031.     add.l    d2,d3
  1032.     and.l    #$fff,d3
  1033.     rts
  1034.  
  1035.  
  1036.  
  1037. ********* Variables *************
  1038. ; Data addresses
  1039. ;
  1040. copmem:        dc.l    0
  1041. dmasaf:        dc.w    0
  1042. grlib:        dc.b    'graphics.library',0
  1043.         even
  1044. bobmem1:    dc.l    0
  1045. bobmem2:    dc.l    0    ;memory for bobs
  1046.         dc.l    0
  1047. logoy:        dc.w    0    ;logo y poss
  1048.         dc.l    0
  1049. agg1:        dc.l    0     ;memory pointer for copper
  1050. megaspr:    dc.l    0
  1051. sprcol:        dc.w    0,$fff,$aaa,$555    ;color for stars
  1052. tom:        ds.w    40        ;empty trash memory
  1053.  
  1054. ** This is the scroll text, only use capital letters **
  1055. ; use a "^" to start the scroll from the beginning.
  1056. ; use one bit numbers below 31 to change speed ex 2,4,8,16 etc
  1057. ; use "#" to make a pause.
  1058.  
  1059. scrtext:    dc.b    8,'NORTH STAR#'
  1060.         dc.b    16,'    AND   #'
  1061.         dc.b    8,'  SILENTS! #'
  1062.         dc.b    4,' PRESENTS A NEW '
  1063.         dc.b    'DEMO MADE FOR THE READERS OF EXCELLER 8'
  1064.         dc.b    ' HOW TO MAKE AN AVERAGE DEMO.. FOR SOURCE '
  1065.         dc.b    'WITH COMMENTS PLUS ALL TOOLS USED SEND 10 MAXELL '
  1066.         dc.b    'MF2 DD DISKS IN AN UNOPENED PACKAGE TO'
  1067.         dc.b    ' EXCELLER 8 '
  1068.         dc.b    'PROGRAMMING, '
  1069.         dc.b    2,'JULIG.7, 252 52 HELSINGBORG, SWEDEN... '
  1070.         dc.b    4,'THEN WE WILL SEND BACK ONE OF THE DISKS WITH '
  1071.         dc.b    'THE SOURCE !!!!        '
  1072.         dc.b    8,' H U R R Y   U P !!!!!!!    '
  1073.         dc.b    4,'IMPORTANT MESSAGE: MAHONEY,KAKTUS AND LORD VEGA IS '
  1074.         dc.b    'STILL NORTH STAR MEMBERS IN FACT MAHONEY AND KAKTUS '
  1075.         dc.b    'ARE THE NEW PROGRAMMING LEADERS SO IF YOU WANT TO '
  1076.         dc.b    'JOIN CONTACT THEM INSTEAD OF ATOM !!!        CALL OUR '
  1077.         dc.b    'BBS IN THE USA: '
  1078.         dc.b    2,'214 422 7378                   ^'
  1079.         even
  1080.  
  1081. scrmem1:    dc.l    0    ;scroll memories
  1082. scrmem2:    dc.l    0
  1083. scrmem3:    dc.l    0
  1084. scradd:        dc.w    0
  1085. scrcount:    dc.w    0
  1086. scrpoint:    dc.l    scrtext
  1087. speed:        dc.w    1    ;current scr speed
  1088. pause:        dc.w    0    ;scr pause if not zero
  1089.  
  1090. colbar1:    dcb.w    4,0        ; 3 red color bars
  1091.         dc.w    $555,$aaa,$fff,$aaa,$555
  1092.         dcb.w    5,0    
  1093.         dc.w    $555,$aaa,$fff,$aaa,$555
  1094.         dcb.w    5,0    
  1095.         dc.w    $555,$aaa,$fff,$aaa,$555,0,0,0,0,0
  1096.  
  1097. colbar2:    ;horizontal grey scale
  1098.         dc.w    $000,$111,$222,$333
  1099.         dc.w    $444,$555,$666,$777
  1100.         dc.w    $888,$999,$aaa,$bbb
  1101.         dc.w    $ccc,$ddd,$eee,$fff
  1102.         dc.w    $eee,$ddd,$ccc,$bbb
  1103.         dc.w    $aaa,$999,$888,$777
  1104.         dc.w    $666,$555,$444,$333
  1105.         dc.w    $222,$111,$000,0,0
  1106.  
  1107. logograd:    dc.w    90    ;grade for logo sin
  1108. wait1:        dc.w    300    ;wait untill logo bumb
  1109. logoby:        dc.w    0    ;ypos for colbar in logo
  1110.  
  1111. colbar3:    dc.w    $eee,$ddd,$ccc,$bbb    ;colbar in logo
  1112.         dc.w    $aaa,$999,$888,$777
  1113.         dc.w    $666,$555,$444,$333
  1114.         dc.w    $222,$111,$000,0,0
  1115.         dc.w    $000,$111,$222,$333
  1116.         dc.w    $444,$555,$666,$777
  1117.         dc.w    $888,$999,$aaa,$bbb
  1118.         dc.w    $ccc,$ddd,$eee,$fff
  1119.  
  1120. bobshow:    ds.l    1        ;pointer to bobmem to show in screen
  1121. bobwork:    ds.l    1        ;work memory
  1122. clear1:        ds.l    50        ;max bobs
  1123. clear2:        ds.l    50
  1124. clearp:        ds.l    1
  1125. boby:        ds.w    50        ;vertical poss for bobs
  1126. bobx:        ds.w    50        ;horizontal poss for bobs
  1127. bobsin:        ds.w    50
  1128. bobcos:        ds.w    50
  1129. frimem:        ds.b    60000*2
  1130.  
  1131. sat:        incbin    'coding:projects/source/oldnorthstardemo/sat'
  1132. nslogoraw:    equ    sat        ;7456
  1133. bobraw:        equ    sat+7456    ;68
  1134. bobmaskraw:    equ    sat+7524    ;34
  1135. fontraw:    equ    sat+7558    ;23056
  1136. sine:        equ    sat+30614    ;900
  1137. slut:        equ    sat+31514
  1138.  
  1139.